FAQ 3.4 How do I find which modules are installed on my system?

[PerlFAQ Server]

This is an excerpt from the latest version perlfaq3.pod, which
comes with the standard Perl distribution. These postings aim to
reduce the number of repeated questions as well as allow the community
to review and update the answers. The latest version of the complete
perlfaq is at http://faq.perl.org .

--------------------------------------------------------------------

3.4: How do I find which modules are installed on my system?

From the command line, you can use the "cpan" command's "-l" switch:

$ cpan -l

You can also use "cpan"'s "-a" switch to create an autobundle file that
"CPAN.pm" understands and can use to re-install every module:

$ cpan -a

Inside a Perl program, you can use the "ExtUtils::Installed" module to
show all installed distributions, although it can take awhile to do its
magic. The standard library which comes with Perl just shows up as
"Perl" (although you can get those with "Module::CoreList").

use ExtUtils::Installed;

my $inst = ExtUtils::Installed->new();
my @modules = $inst->modules();

If you want a list of all of the Perl module filenames, you can use
"File::Find::Rule":

use File::Find::Rule;

my @files = File::Find::Rule->
extras({follow => 1})->
file()->
name( '*.pm' )->
in( @INC )
;

If you do not have that module, you can do the same thing with
"File::Find" which is part of the standard library:

use File::Find;
my @files;

find(
{
wanted => sub {
push @files, $File::Find::fullname
if -f $File::Find::fullname && /\.pm$/
},
follow => 1,
follow_skip => 2,
},
@INC
);

print join "\n", @files;

If you simply need to quickly check to see if a module is available, you
can check for its documentation. If you can read the documentation the
module is most likely installed. If you cannot read the documentation,
the module might not have any (in rare cases):

$ perldoc Module::Name

You can also try to include the module in a one-liner to see if perl
finds it:

$ perl -MModule::Name -e1



--------------------------------------------------------------------

The perlfaq-workers, a group of volunteers, maintain the perlfaq. They
are not necessarily experts in every domain where Perl might show up,
so please include as much information as possible and relevant in any
corrections. The perlfaq-workers also don't have access to every
operating system or platform, so please include relevant details for
corrections to examples that do not work on particular platforms.
Working code is greatly appreciated.

If you'd like to help maintain the perlfaq, see the details in
perlfaq.pod.