FAQ 5.16 How come when I open a file read-write it wipes it out?

Discussion in 'Perl Misc' started by PerlFAQ Server, Apr 26, 2011.

  1. This is an excerpt from the latest version perlfaq5.pod, which
    comes with the standard Perl distribution. These postings aim to
    reduce the number of repeated questions as well as allow the community
    to review and update the answers. The latest version of the complete
    perlfaq is at http://faq.perl.org .

    --------------------------------------------------------------------

    5.16: How come when I open a file read-write it wipes it out?

    Because you're using something like this, which truncates the file
    *then* gives you read-write access:

    open my $fh, '+>', '/path/name'; # WRONG (almost always)

    Whoops. You should instead use this, which will fail if the file doesn't
    exist:

    open my $fh, '+<', '/path/name'; # open for update

    Using ">" always clobbers or creates. Using "<" never does either. The
    "+" doesn't change this.

    Here are examples of many kinds of file opens. Those using "sysopen" all
    assume that you've pulled in the constants from "Fcntl":

    use Fcntl;

    To open file for reading:

    open my $fh, '<', $path or die $!;
    sysopen my $fh, $path, O_RDONLY or die $!;

    To open file for writing, create new file if needed or else truncate old
    file:

    open my $fh, '>', $path or die $!;
    sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT or die $!;
    sysopen my $fh, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666 or die $!;

    To open file for writing, create new file, file must not exist:

    sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT or die $!;
    sysopen my $fh, $path, O_WRONLY|O_EXCL|O_CREAT, 0666 or die $!;

    To open file for appending, create if necessary:

    open my $fh, '>>' $path or die $!;
    sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT or die $!;
    sysopen my $fh, $path, O_WRONLY|O_APPEND|O_CREAT, 0666 or die $!;

    To open file for appending, file must exist:

    sysopen my $fh, $path, O_WRONLY|O_APPEND or die $!;

    To open file for update, file must exist:

    open my $fh, '+<', $path or die $!;
    sysopen my $fh, $path, O_RDWR or die $!;

    To open file for update, create file if necessary:

    sysopen my $fh, $path, O_RDWR|O_CREAT or die $!;
    sysopen my $fh, $path, O_RDWR|O_CREAT, 0666 or die $!;

    To open file for update, file must not exist:

    sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT or die $!;
    sysopen my $fh, $path, O_RDWR|O_EXCL|O_CREAT, 0666 or die $!;

    To open a file without blocking, creating if necessary:

    sysopen my $fh, '/foo/somefile', O_WRONLY|O_NDELAY|O_CREAT
    or die "can't open /foo/somefile: $!":

    Be warned that neither creation nor deletion of files is guaranteed to
    be an atomic operation over NFS. That is, two processes might both
    successfully create or unlink the same file! Therefore O_EXCL isn't as
    exclusive as you might wish.

    See also the new perlopentut.



    --------------------------------------------------------------------

    The perlfaq-workers, a group of volunteers, maintain the perlfaq. They
    are not necessarily experts in every domain where Perl might show up,
    so please include as much information as possible and relevant in any
    corrections. The perlfaq-workers also don't have access to every
    operating system or platform, so please include relevant details for
    corrections to examples that do not work on particular platforms.
    Working code is greatly appreciated.

    If you'd like to help maintain the perlfaq, see the details in
    perlfaq.pod.
     
    PerlFAQ Server, Apr 26, 2011
    #1
    1. Advertising

Want to reply to this thread or ask your own question?

It takes just 2 minutes to sign up (and it's free!). Just click the sign up button to choose a username and then you can ask your own questions on the forum.
Similar Threads
  1. JT
    Replies:
    5
    Views:
    372
  2. Replies:
    1
    Views:
    615
    GArlington
    Aug 31, 2007
  3. SDA
    Replies:
    0
    Views:
    322
  4. Replies:
    0
    Views:
    337
  5. Simon Strandgaard

    [bug] String#split wipes result

    Simon Strandgaard, May 31, 2004, in forum: Ruby
    Replies:
    2
    Views:
    110
    Simon Strandgaard
    May 31, 2004
Loading...

Share This Page