regex replace credit card numbers with *

[cldmismgr]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}
print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;
print "$addr\n$star\n";

Thanks for any comments or advice
Craig

 

[A. Sinan Unur]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}
print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;
print "$addr\n$star\n";

Well, do you just have a string of nine digits, or is there anything
special about the way the credit card number is formatted?

use strict ;
use warnings;

my $cc = '123456789012345';
$cc =~ tr/0123456789/*/;

print "$cc\n";

__END__

perldoc perlop for tr.

Sinan

 

[Paul Lalli]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}
print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;
print "$addr\n$star\n";

Well, do you just have a string of nine digits, or is there anything
special about the way the credit card number is formatted?

use strict ;
use warnings;

my $cc = '123456789012345';
$cc =~ tr/0123456789/*/;

print "$cc\n";

__END__

Er, the output of that code is a series of 15 *'s. Doesn't seem to be
what the OP asked for.

 

[Paul Lalli]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}

This is just silly. Why are you using an entire for loop just to get a
repeated character?

my $star = '*' x (length ($addr) - 4);

print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;

Or, do it all at once:
my $size = length($addr) - 4;
$addr =~ s/^\d{$size}/'*' x $size/e;

Or, if you're can guarantee to yourself that the string will only have
digits to begin with:

substr($addr, 0, $size) = '*' x $size;

print "$addr\n$star\n";

Hope this helps,
Paul Lalli

 

[cldmismgr]

I could not make your first suggestion work. I got the string back
unchanged.
The second one works great for any size string.
New light has been shed on the mysterious regex. For me anyway.
Thanks

 

[Paul Lalli]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.

You could use a look-ahead assertion for that:
$addr =~ s/\d(?=\s{4})/*/g;

Small but significant typo - you want to look for 4 digits remaining,
not spaces.

$addr =~ s/\d(?=\d{4})/*/g;

Paul Lalli

 

[Tad McClellan]

Er, the output of that code is a series of 15 *'s. Doesn't seem to be
what the OP asked for.

So let's fix it with an lvalue substr():

substr($cc, 0, -4) =~ tr/0-9/*/;

 

[Paul Lalli]

an lvalue substr():

substr($cc, 0, -4) =~ tr/0-9/*/;

Ooh, I like! I was trying to think of a good way of doing this with
substr, but I was blanking on remembering the "negative limit" feature
of the function.

Thanks, Tad.

Paul Lalli

 

[axel]

I have this little piece of code to replace all but the last 4 numbers
in a credit card number with *'s. Is there a better way to do this? I
tried using just a regex but everything I tried failed. For example
s/^[0-9]{9}/*/ replaced this first 9 digits with one *. The idea is to
replace each digit with an asterick and leave the last four digits
alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}
print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;
print "$addr\n$star\n";

One solution would be as follows - note also allows for non-digits
to be interspersed (and ignored).

#!/usr/bin/perl

use strict;
use warnings;

my $st = "*";
my $addr = '1245-4536-8904-2345';
print $addr, "\n";

$addr =~ s/\d/$st/ for (1 .. ($addr =~ tr/0-9//) - 4);

print $addr, "\n";

__END__

Output:

1245-4536-8904-2345
****-****-****-2345

Axel

 

[A. Sinan Unur]

I have this little piece of code to replace all but the last 4
numbers in a credit card number with *'s. Is there a better way to
do this? I tried using just a regex but everything I tried failed.
For example s/^[0-9]{9}/*/ replaced this first 9 digits with one *.
The idea is to replace each digit with an asterick and leave the
last four digits alone.
$st = "*";
$addr = '123456789012345';
$size = length($addr) - 4;
for ($i=0;$i < $size; $i++) {
$star .= $st;
}
print "$addr\n";
$addr =~ s/^[0-9]{$size}/$star/;
print "$addr\n$star\n";

Well, do you just have a string of nine digits, or is there anything
special about the way the credit card number is formatted?

use strict ;
use warnings;

my $cc = '123456789012345';
$cc =~ tr/0123456789/*/;

print "$cc\n";

__END__

Er, the output of that code is a series of 15 *'s. Doesn't seem to be
what the OP asked for.

Sorry, I missed that part.

One way to do that with the substitution operator is:

use strict ;
use warnings;

my $cc = '123456789012345';
$cc =~ s/\d{11}(?=\d{4})/('*') x 11/e;

print "$cc\n";

__END__

D:\Home\asu1\UseNet\clpmisc> c
***********2345

Sinan

PS: I am assuming that the OP incorrectly stated that he wanted replace
the first 9 digits and leave the last four alone because the string
contains 15 characters.