Peter said:
Yes, my SP has FOR XML AUTO, ELEMENTS. It returns the results
as XML.
Now, I have a VBscript program that dynamically generates HTML
output. I want to run my SP from VBScript, and insert the XML as
a data island in my HTML.
I have some code somewhere that uses a Stream to get te XML. Let me look for
it: ... ah! Here it is:
<%@ Language=VBScript %>
<%
option explicit
dim cn, rs,sQuery, cmd, xmldoc
Const adExecuteStream = &H00000400
Const adCmdText = &H0001
set cn=server.CreateObject("adodb.connection")
cn.open "provider=sqloledb;data source=????;" & _
"user id = ???; password=????;initial catalog=northwind"
Set xmldoc=server.createobject("msxml2.domdocument")
Set cmd = Server.CreateObject("ADODB.Command")
Set cmd.ActiveConnection = cn
sQuery = "SELECT * FROM PRODUCTS ORDER BY PRODUCTNAME FOR XML auto"
cmd.CommandText = sQuery
cmd.Properties("xml root").Value = "root"
cmd.Properties("Output Stream") = xmldoc
cmd.Execute , , adExecuteStream + adCmdText
set cmd=nothing
cn.close
set cn=nothing
%>
<html>
....
<XML id="xmlData">
<%=xmldoc.xml%>
</XML>
</html>
HTH,
Bob Barrows