Printing an array of hash refs

[Tony N.]

I'm using the following code to print an array of hash refs. It seems
to me there should be a more concise way to do this. I don't like the
trailing \t or the extra line of code to get the \n. Any pointers
would be appreciated.

print "$_\t" for sort keys %{$rows[0]};
print "\n";

for my $row (@rows) {
print "$row->{$_}\t" for sort keys %{$row};
print "\n";

}

 

[Paul Lalli]

I'm using the following code to print an array of hash refs. It seems
to me there should be a more concise way to do this. I don't like the
trailing \t or the extra line of code to get the \n. Any pointers
would be appreciated.
for my $row (@rows) {
print "$row->{$_}\t" for sort keys %{$row};
print "\n";
}

for my $row (@rows){
print (join ("\t", sort keys %$row), "\n");
}

Paul Lalli

 

[Mark Clements]

I'm using the following code to print an array of hash refs. It seems
to me there should be a more concise way to do this. I don't like the
trailing \t or the extra line of code to get the \n. Any pointers
would be appreciated.

print "$_\t" for sort keys %{$rows[0]};
print "\n";

for my $row (@rows) {
print "$row->{$_}\t" for sort keys %{$row};
print "\n";

}

check out Data:umper.

Mark

 

[Shawn Corey]

for my $row (@rows){
print (join ("\t", sort keys %$row), "\n");
}

Paul Lalli

Isn't it?

print join( "\t", map { $row->{$_} } sort keys %$row ), "\n";

--- Shawn

 

[Paul Lalli]

Isn't it?

print join( "\t", map { $row->{$_} } sort keys %$row ), "\n";

Ah, quite correct. I neglected to realize the OP wanted the hash values
rather than the hash keys. Thanks for the correction.

Paul Lalli

 

[John W. Krahn]

I'm using the following code to print an array of hash refs. It seems
to me there should be a more concise way to do this. I don't like the
trailing \t or the extra line of code to get the \n. Any pointers
would be appreciated.

print "$_\t" for sort keys %{$rows[0]};
print "\n";

for my $row (@rows) {
print "$row->{$_}\t" for sort keys %{$row};
print "\n";

}

print map { my $row = $_; join( "\t", map $row->{$_}, sort keys %$row ) . "\n"
} @rows;


John

 

[Tony N.]

Ah, quite correct. I neglected to realize the OP wanted the hash values
rather than the hash keys. Thanks for the correction.

Thanks Paul and Shawn. That's exactly what I was looking for. The
first print join I'll use once for the headings (hash keys) and the
second for all of the values.

Regards,
Tony

 

[Jay Tilton]

(e-mail address removed) (Tony N.) wrote:

: I'm using the following code to print an array of hash refs. It seems
: to me there should be a more concise way to do this. I don't like the
: trailing \t or the extra line of code to get the \n. Any pointers
: would be appreciated.
:
: print "$_\t" for sort keys %{$rows[0]};
: print "\n";
:
: for my $row (@rows) {
: print "$row->{$_}\t" for sort keys %{$row};
: print "\n";
: }

{
local($, , $\) = ("\t", "\n");
print sort keys %{$rows[0]};
print @$_{sort keys %$_} for @rows;
}

 

[Ben Morrow]

Isn't it?

print join( "\t", map { $row->{$_} } sort keys %$row ), "\n";

I would prefer

{
local ($,, $\) = ("\t", "\n");
print map $row->{$_}, sort keys %$row;
}

or maybe with a hash slice

{
local ($,, $\) = ("\t", "\n");
print @{$row}{sort keys %$row};
}

Ben

 

[Tony N.]

(e-mail address removed) (Tony N.) wrote:

{
local($, , $\) = ("\t", "\n");
print sort keys %{$rows[0]};
print @$_{sort keys %$_} for @rows;
}

Thanks Jay. I liked this technique, so I created a second version of
the program using this (I had already implemented the technique from
Paul and Shawn).

I had to make a modification and was hoping you guys would look at.
The hash ref array is populated using DBI and my SQL statement was
missing an outer join. After I fixed that now I have the possibility
of null values coming the DB server.

Thanks to everyone who responded. I learned a lot from your examples.


Modified version of Jay's technique:
{
local ($, , $\) = ("\t", "\n");
print sort keys %{$rows[0]};
for my $row (@rows) {
print map {$row->{$_}?$row->{$_}:'' } sort keys %{$row};
}
}

Modified version of Paul's and Shawn's technique:
print join("\t", sort keys %{$rows[0]}), "\n";
for my $row (@rows) {
print join("\t", map { $row->{$_} ? $row->{$_}:'' } sort keys %$row),
"\n";

}

 

[Joe Smith]

The hash ref array is populated using DBI and my SQL statement was
missing an outer join. After I fixed that now I have the possibility
of null values coming the DB server.

print map {$row->{$_}?$row->{$_}:'' } sort keys %{$row};

That will print '0' as '', which is bad if 0 is a legitmate value.

print map {(defined $row->{$_}) ? $row->{$_} : '' } sort keys %{$row};

-Joe

 

[Tony N.]

That will print '0' as '', which is bad if 0 is a legitmate value.

print map {(defined $row->{$_}) ? $row->{$_} : '' } sort keys %{$row};

-Joe

Good point.

Thanks,
Tony